COMMENT ⊗   VALID 00028 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00004 00002	% This script alphabet is based on traditional Chancery style, except
C00006 00003	"Script A" spen
C00007 00004	"Script B" spen
C00008 00005	"Script C" spen
C00009 00006	"Script D" spen
C00010 00007	"Script E" spen
C00011 00008	"Script F" spen
C00012 00009	"Script G" spen
C00013 00010	"Script H" spen
C00014 00011	"Script I" spen
C00015 00012	"Script J" spen
C00016 00013	"Script K" spen
C00017 00014	"Script L" spen
C00018 00015	"Script M" spen
C00019 00016	"Script N" spen
C00020 00017	"Script O" spen
C00021 00018	"Script P" spen
C00022 00019	"Script Q" spen
C00023 00020	"Script R" spen
C00024 00021	"Script S" spen
C00025 00022	"Script T" spen
C00026 00023	"Script U" spen
C00027 00024	"Script V" spen
C00028 00025	"Script W" spen
C00029 00026	"Script X" spen
C00030 00027	"Script Y" spen
C00031 00028	"Script Z" spen
C00033 ENDMK
C⊗;
% This script alphabet is based on traditional Chancery style, except
% that descenders are eliminated, and the letters I, J, Q, T have been
% modified to accord with modern practice suitable for use with
% mathematics. All the letters are drawn with a single pen, whose
% dimensions are \\{pw} by \\{pwv}, rotated to the angle whose tangent is 2.
new aa,bb,aaa,bbb,spa,spb,spc;	% variables to specify the spen
aa=(sqrt 1.25)(pwv.pixels+blacker);
bb=(sqrt 1.25)(pw.pixels+blacker);
aaa=1/aa/aa; bbb=1/bb/bb;
spen(aaa+4bbb,4aaa-4bbb,4aaa+bbb,0,0,0,0);
no penreset;
new cor,corr;	% commonly used spacing corrections
cor=phh.slant/pu;
if cor>1: corr=1;
else: corr=cor;
fi;
"Script A"; spen;
call charbegin(`A,12,0,0,phh,0,phh.slant-(3.75-mi)pu);
x1=7.25u; y1=hh;
x2=4u; y2=.59hh;
x3=4.5u; y3=.27hh;
x4=2.75u; y4=0;
x5=1.5u; y5=.07hh;
x6=8u; y6=.35hh;
x7=10u; y7=0;
x8=2.5u; y8=.35hh;
draw 1{3(x2-x1),y2-y1}..2{x3-x2,y3-y2}..3{x3-x2,y3-y2}..
	4{-1,0}..5{x5-x4,3(y5-y4)};	% left diagonal
draw 1{0,1}..6{x7-x6,1.5(y7-y6)}..7{1.5(x7-x6),y7-y6};	% right diagonal
draw 8..6.	% bar
"Script B"; spen;
call charbegin(`B,12,mi.corr,-.5mi.cor+2mi,phh,0,mi[.5phh.slant-pu,2pu]);
x1=3u; y1=.95hh;
x2=3.5u; y2=.48hh;
x3=3u; y3=0;
x4=1.75u; y4=.9hh;
x5=5.5u; y5=hh;
x6=8.25u; y6=.74hh;
x7=(sqrt .5)[x2,x6]; y7=(sqrt .5)[y6,y2];
x8=10u; y8=.3hh;
x9=6.5u; y9=0;
draw 1{2(x2-x1),y2-y1}..2{0,-1}..3{2(x3-x2),y3-y2};	% stem
draw 4{x5-x4,3(y5-y4)}..5{1,0}..6{0,-1}..
	7{x2-x6,y2-y6}..2{-1,0};	% upper bowl
draw 7{1,0}..8{0,-1}..9{-1,0}..3.	% lower bowl
"Script C"; spen;
call charbegin(`C,12,.5mi.cor,-.2mi.cor,phh,0,
				mi[phh.slant-2.25pu,.8phh.slant-2.25pu]);
x1=8.5u; y1=.84hh;
x2=6.5u; y2=hh;
x3=2u; y3=.52hh;
x4=6.5u; y4=0;
x5=10u; y5=.21hh;
draw 1{x2-x1,4(y2-y1)}..2{-1,0}..3{0,-1}..4{1,0}..
	5{x5-x4,4(y5-y4)}.	% bowl
"Script D"; spen;
call charbegin(`D,12,mi.corr,-.6mi.cor+2.5mi,phh,0,mi[.6phh.slant-pu,2.5pu]);
x1=3u; y1=.95hh;
x2=3.5u; y2=.48hh;
x3=3u; y3=0;
x4=1.75u; y4=.9hh;
x5=5.5u; y5=hh;
x6=10u; y6=.55hh;
draw 1{2(x2-x1),y2-y1}..2{0,-1}..3{2(x3-x2),y3-y2};	% stem
draw 4{x5-x4,3(y5-y4)}..5{1,0}..6{0,-1}..3{-1,0}.	% bowl
"Script E"; spen;
call charbegin(`E,10.5,.2mi.cor,-.2mi.cor+mi,phh,0,mi[phh.slant-1.5pu,.8phh.slant+.5pu]);
x1=8u; y1=.84hh;
x2=5.5u; y2=hh;
x3=2.75u; y3=.84hh;
x4=6u; y4=.56hh;
x5=2u; y5=.3hh;
x6=5.5u; y6=0;
x7=8.5u; y7=.12hh;
draw 1{x2-x1,4(y2-y1)}..2{-1,0}..3{0,-1}..4{1,0};	% upper bowl
draw 4{-1,0}..5{0,-1}..6{1,0}..7{x7-x6,3(y7-y6)}.	% lower bowl
"Script F"; spen;
call charbegin(`F,12.5,mi.corr,mi(4-.5cor),
				phh,0,mi[phh.slant-pu,.5phh.slant+2.5pu]);
x1=1.75u; y1=.86hh;
x2=9u; y2=hh;
x3=6.5u; y3=.59hh;
x4=6.5u; y4=.27hh;
x5=4.25u; y5=0;
x6=3u; y6=.07hh;
x7=4u; y7=.52hh;
x8=9u; y8=.52hh;
x9=10.5u; y9=hh;
draw 1{x2-x1,5(y2-y1)}..2{1,0};	% shoulder
draw 2{-1,0}..3{0,-1}..4{0,-1}..5{-1,0}..6{x6-x5,3(y6-y5)};	% stem
draw 7..8;	% bar
draw 2..9.	% extension so as not to look like European J
"Script G"; spen;
call charbegin(`G,11.5,0,-.25mi.cor,phh,pd,mi[.5phh.slant-1.5pu,.75corr.pu]);
x1=8.5u; y1=.82hh;
x2=5.5u; y2=hh;
x3=2.5u; y3=.56hh;
x4=5.5u; y4=.16hh;
x5=9u; y5=.53hh;
x6=9.5u; y6=.23hh;
x7=5.5u; y7=-d;
x8=2u; y8=-.33d;
draw 1{x2-x1,4(y2-y1)}..2{-1,0}..3{0,-1}..4{1,0}..5{0,1};	% upper bowl
draw 5{2(x6-x5),y6-y5}..6{0,-1}..7{-1,0}..8{x8-x7,3(y8-y7)}.	% tail
"Script H"; spen;
call charbegin(`H,12,mi.corr,0,phh,0,phh.slant-(2-mi)pu);
x1=1.5u; y1=hh;
x2=5u; y2=.4hh;
x3=3u; y3=0;
x4=9u; y4=hh;
x5=8.5u; y5=.4hh;
x6=10u; y6=0;
x7=3u; y7=.45hh;
x8=9u; y8=.45hh;
draw 1{5(x2-x1),y2-y1}..2{0,-1}..3{-1,0};	% left stem
draw 4{2(x5-x4),y5-y4}..5{0,-1}..6{3(x6-x5),y6-y5};	% right stem
draw 7{7u-x7,.15hh-y7}..8{x8-7u,y8-.15hh}.	% bar
"Script I"; spen;
call charbegin(`I,9,0,0,phh,0,phh.slant-(1-mi)pu);
x1=4.5u; y1=.95hh;
x2=5u; y2=.52hh;
x3=4.5u; y3=.05hh;
x4=2u; y4=hh;
x5=7u; y5=hh;
x6=2u; y6=0;
x7=7u; y7=0;
draw 1{2(x2-x1),y2-y1}..2{0,-1}..3{2(x3-x2),y3-y2};	% stem
draw 4{x1-x4,3(y1-y4)}..1{1,0}..5{x5-x1,3(y5-y1)};	% upper serif
draw 6{x3-x6,3(y3-y6)}..3{1,0}..7{x7-x3,3(y7-y3)}.	% lower serif
"Script J"; spen;
call charbegin(`J,10,0,-.5mi.cor+3mi,phh,0,
				mi[phh.slant-pu,.5phh.slant+1.25pu]);
x1=6.5u; y1=.95hh;
x2=7u; y2=.52hh;
x3=4u; y3=0;
x4=1.5u; y4=.18hh;
x5=4u; y5=hh;
x6=8u; y6=hh;
draw 1{2(x2-x1),y2-y1}..2{0,-1}..
	3{-1,0}..4{x4-x3,3(y4-y3)};	% stem and tail
draw 5{x1-x5,3(y1-y5)}..1{1,0}..6{x6-x1,3(y6-y1)}.	% serif
"Script K"; spen;
call charbegin(`K,13,0,0,phh,0,phh.slant-(2-mi)pu);
x1=1.75u; y1=hh;
x2=2.75u; y2=.31hh;
x3=2u; y3=0;
x4=10u; y4=hh;
x5=6u; y5=.82hh;
x6=3.75u; new aa; x6=aa[x2,x5]; y6=aa[y2,y5];
x7=11u; y7=0;
draw 1{2(x2-x1),y2-y1}..2{0,-1}..3{-1,0};	% stem
draw 4{-1,0}..5{x2-x5,y2-y5}..2;	% upper diagonal
draw 6{x7-x6,1.25(y7-y6)}..7{1.25(x7-x6),y7-y6}.	% lower diagonal
"Script L"; spen;
call charbegin(`L,13,0,0,phh,0,0);
x1=4.25u; y1=hh;
x2=2.5u; y2=.77hh;
x3=3.25u; y3=.26hh;
x4=2u; y4=0;
x5=6u; y5=0;
x6=11u; y6=0;
draw 1{-1,0}..2{x3-x2,y3-y2}..3{x3-x2,y3-y2}..4{-60u,-hh};	% stem
draw 4{30u,hh}..5{30u,-hh}..6{30u,hh}.	% bar
"Script M"; spen;
call charbegin(`M,17,0,0,phh,0,0);
x1=2.5u; y1=hh;
x2=4.5u; y2=.23hh;
x3=3.25u; y3=0;
x4=2u; y4=.07hh;
x5=9u; y5=.15hh;
x6=11u; y6=.97hh;
x7=12.5u; y7=.27hh;
x8=15u; y8=0;
draw 1{2(x2-x1),y2-y1}..2{0,-1}..
	3{-1,0}..4{x4-x3,3(y4-y3)};	% first diagonal
draw 1{x5-x1,.75(y5-y1)}..5{.75(x5-x1),y5-y1};	% second diagonal
draw 5..6;	% third diagonal
draw 6..7{x7-x6,y7-y6}..8{1,0}.	% fourth diagonal
"Script N"; spen;
call charbegin(`N,13,0,0,phh,0,phh.slant-(1-mi)pu);
x1=3.5u; y1=hh;
x2=4.75u; y2=.27hh;
x3=3.25u; y3=0;
x4=2u; y4=.07hh;
x5=11u; y5=0;
x6=11u; y6=hh;
draw 1{2(x2-x1),y2-y1}..2{0,-1}..3{-1,0}..4{x4-x3,3(y4-y3)};	% left stem
draw 1{x5-x1,2(y5-y1)}..5{2(x5-x1),y5-y1};	% diagonal
draw 5{-3u,hh}..6{3u,hh}.	% right stem
"Script O"; spen;
call charbegin(`O,13,.25mi.cor,-.75mi.cor+2.5mi,phh,0,mi[.75phh.slant-pu,2.5pu]);
x1=8u; y1=.94hh;
x2=6.5u; y2=hh;
x3=2u; y3=.46hh;
x4=6.5u; y4=0;
x5=11u; y5=.38hh;
x6=8u; y6=.88hh;
x7=6.5u; y7=.83hh;
draw 1{x2-x1,2(y2-y1)}..2{-1,0}..3{0,-1}..4{1,0}..5{0,1}..
	6{-1,0}..7{x7-x6,4(y7-y6)}.	% bowl
"Script P"; spen;
call charbegin(`P,11,0,-.5mi.cor+3mi,phh,0,mi[.8phh.slant-pu,.3phh.slant+3pu]);
x1=3u; y1=.97hh;
x2=3.5u; y2=.4hh;
x3=2u; y3=0;
x4=1.5u; y4=.95hh;
x5=5.5u; y5=hh;
x6=9u; y6=.7hh;
draw 1{2(x2-x1),y2-y1}..2{0,-1}..3{-1,0};	% stem
draw 4{x5-x4,4(y5-y4)}..5{1,0}..6{0,-1}..2{-1,0}.	% bowl
"Script Q"; spen;
call charbegin(`Q,15,0,0,phh,.3pd,0);
x1=8u; y1=.95hh;
x2=6.5u; y2=hh;
x3=2u; y3=.53hh;
x4=6.5u; y4=.15hh;
x5=11u; y5=.47hh;
x6=8u; y6=.88hh;
x7=6.5u; y7=.84hh;
x8=2.5u; y8=-.3d;
x9=7.75u; y9=-.3d;
x10=13u; y10=-.3d;
draw 1{x2-x1,2(y2-y1)}..2{-1,0}..3{0,-1}..4{1,0}..5{0,1}..
	6{-1,0}..7{x7-x6,4(y7-y6)};	% bowl
draw 5{0,-1}..8{-120u,-hh};	% link
draw 8{60u,hh}..9{60u,-hh}..10{60u,hh}.	% bar
"Script R"; spen;
call charbegin(`R,14,0,0,phh,0,0);
x1=3u; y1=.97hh;
x2=3.5u; y2=.4hh;
x3=2u; y3=0;
x4=1.5u; y4=.95hh;
x5=5.5u; y5=hh;
x6=9u; y6=.7hh;
x7=4.25u; y7=.4hh;
y8=.06hh; % $x↓8$ will be defined shortly
x9=10.5u; y9=0;
(x9-x8)/(y9-y8)=2(x8-x7)/(y8-y7);
x10=12u; y10=.08hh;
draw 1{2(x2-x1),y2-y1}..2{0,-1}..3{-1,0};	% stem
draw 4{x5-x4,4(y5-y4)}..5{1,0}..6{0,-1}..2{-1,0};	% bowl
draw 7..8{x8-x7,y8-y7}..9{1,0}..10{x10-x9,3(y10-y9)}.	% diagonal
"Script S"; spen;
call charbegin(`S,10,0,-mi(cor-.75corr)+2.5mi,phh,0,mi[phh.slant-1.75pu,2.5pu]);
x1=7.25u; y1=.8hh;
x2=5u; y2=hh;
x3=2u; y3=.82hh;
x4=5u; y4=.48hh;
x5=8u; y5=.2hh;
x6=5u; y6=0;
x7=2u; y7=.18hh;
draw 1{x2-x1,4(y2-y1)}..2{-1,0}..3{0,-1}..4{32u,-hh}..5{0,-1}..
	6{-1,0}..7{x7-x6,3(y7-y6)}.	% stroke
"Script T"; spen;
call charbegin(`T,15,.8mi.cor,2.5mi,phh,0,phh.slant+(3.5mi-1)pu);
x1=2u; y1=.9hh;
x2=8.5u; y2=.95hh;
x3=13u; y3=hh;
x4=8u; y4=.44hh;
x5=10u; y5=0;
draw 1{6u,hh}..2{60u,-hh}..3{6u,hh};	% bar
draw 2{2(x4-x2),y4-y2}..4{0,-1}..5{1,0}.	% stem
"Script U"; spen;
call charbegin(`U,14,.8mi.cor,0,phh,0,phh.slant-(3.5-mi)pu);
x1=1.5u; y1=.93hh;
x2=3u; y2=hh;
x3=4u; y3=.74hh;
x4=3.5u; y4=.35hh;
x5=6.5u; y5=0;
x6=9.5u; y6=.33hh;
x7=9.5u; y7=.95hh;
x8=11u; y8=0;
x9=12u; y9=.09hh;
draw 1{x2-x1,3(y2-y1)}..2{1,0}..3{x4-x3,y4-y3}..4{x4-x3,y4-y3}..
	5{1,0}..6{0,1}..7;	% stroke and stem
draw 6{0,-1}..8{1,0}..9{x9-x8,4(y9-y8)}.	% point
"Script V"; spen;
call charbegin(`V,14,.8mi.cor,0,phh,0,phh.slant-(1.5-mi)pu);
x1=1.5u; y1=.95hh;
x2=3.5u; y2=hh;
x3=9u; y3=0;
x4=12u; y4=.59hh;
x5=10.5u; y5=.97hh;
draw 1{x2-x1,2(y2-y1)}..2{1,0}..3{2u,-hh};	% left diagonal
draw 3{3(x4-x3),y4-y3}..4{0,1}..5{3(x5-x4),y5-y4}.	% right diagonal
"Script W"; spen;
call charbegin(`W,17,.8mi.cor,0,phh,0,phh.slant-(1.5-mi)pu);
x1=1.5u; y1=.95hh;
x2=3.5u; y2=hh;
x3=7u; y3=0;
x4=9.75u; y4=.97hh;
x5=12u; y5=0;
x6=15u; y6=.59hh;
x7=14u; y7=.96hh;
draw 1{x2-x1,2(y2-y1)}..2{1,0}..3{0,-1};	% first diagonal
draw 3{x7-x3,y7-y3}..4{2(x4-x5),y4-y5};	% second diagonal
draw 4{2(x5-x4),y5-y4}..5{0,-1};	% third diagonal
draw 5{3(x6-x5),y6-y5}..6{0,1}..7{2(x7-x6),y7-y6}.	% fourth diagonal
"Script X"; spen;
call charbegin(`X,13,0,0,phh,0,phh.slant-(2-1.5mi)pu);
x1=1.5u; y1=.95hh;
x2=2.5u; y2=hh;
x3=5.5u; y3=.45hh;
x4=2.5u; y4=0;
x5=10u; y5=hh;
x6=10u; y6=0;
x7=11u; y7=.05hh;
x8=2u; y8=.025hh;
draw 1{x2-x1,3(y2-y1)}..2{1,0}..3{0,-1}..
	4{-1,0}..8{x8-x4,3(y8-y4)};	% left stroke
draw 5{-1,0}..3{0,-1}..6{1,0}..7{x7-x6,3(y7-y6)}.	% right stroke
"Script Y"; spen;
call charbegin(`Y,13,.8mi.cor,-.5mi.cor,phh,pd,mi[phh.slant-pu,.5phh.slant]);
x1=2u; y1=.95hh;
x2=3.5u; y2=hh;
x3=5u; y3=.4hh;
x4=7.75u; y4=.14hh;
x5=11u; y5=.97hh;
x6=11u; y6=.2hh;
x7=7.5u; y7=-d;
x8=4u; y8=-.54d;
draw 1{x2-x1,3(y2-y1)}..2{1,0}..3{0,-1}..4{1,0}..5{0,1};	% stroke
draw 5..6{0,-1}..7{-1,0}..8{x8-x7,3(y8-y7)}.	% stem and tail
"Script Z"; spen;
call charbegin(`Z,13,0,0,phh,0,phh.slant-(2-mi)pu);
x1=1.75u; y1=.9hh;
x2=6u; y2=.95hh;
x3=10u; y3=hh;
x4=6.5u; y4=.5hh;
x5=2u; y5=0;
x6=7u; y6=.05hh;
x7=11u; y7=.1hh;
draw 1{6u,hh}..2{60u,-hh}..3{6u,hh};	% upper bar
draw 3{x4-x3,2(y4-y3)}..4{x5-x3,y5-y3}..5{x5-x4,2(y5-y4)};	% diagonal
draw 5{6u,hh}..6{60u,-hh}..7{6u,hh}.	% lower bar